Limita funkce

Tomáš Kalvoda, FIT CVUT, BI-ZMA 2013/2014

Demonstrujme definice limity funkce, nejprve ale připomeňme samotnou definici:

Je-li f reálná funkce reálné proměnné definovaná na okolí bodu a∈(OverBar[ℝ]) s možnou vyjímkou bodu a samotného. Řekneme, že f má limitu v bodě a rovnu c∈(OverBar[ℝ]), právě když pro každé okolí (Subscript[H, c]) bodu c existuje okolí (Subscript[H, a]) bodu a takové, že pokud x∈(Subscript[H, a])-{a} platí f(x)∈(Subscript[H, c]).

Připomeňme také definici okolí bodů z rozšířené reálné osy (OverBar[ℝ]). Pokud a∈ℝ, pak velikost okolí je udána kladným reálným parametrem ϵ,

(Subscript[H, a])(ϵ)=(a-ϵ,a+ϵ).

Pokud a=+∞, pak pro α∈ℝ klademe

(Subscript[H, +∞])(α)=(α,+∞).

Podobně v případě a=-∞ máme pro α∈ℝ

(Subscript[H, -∞])(α)=(-∞,-α).

a,c∈ℝ

sin(x)->sin(1) když x->1.

Manipulate[
a=.8;
c=Sin[.8];
Show[
Plot[Sin[x],{x,-π/2,π},
PlotStyle->{Blue,Thick},
AxesLabel->{Style["x",Italic,14],Style["sin(x)",Italic,14]},
PlotRange->{-1.5,2},
ImageSize->400,
Ticks->{{-π/2,0,π,2π},{-1,0,1}},
TicksStyle->14
],
Graphics[{Black,Disk[{0,c},.03],Disk[{a,0},.03]}],
Graphics[{Gray,Dashed,Line[{{-π/2,c},{π,c}}]}],
Graphics[{Green,Opacity[.2],Rectangle[{-π/2,c-ϵ},{π,c+ϵ}]}],
Graphics[{Green,Thickness[.01],Line[{{0,c-ϵ},{0,c+ϵ}}]}],
Graphics[{Text[Style["c",Italic,14],{-.1,c-.1}]}],
Plot[Sin[x],{x,a-δ,a+δ},PlotStyle->{Red,Thick}],
Graphics[{Opacity[.2],Lighter[Red],Rectangle[{a-δ,-1.5},{a+δ,2}]}],
Graphics[{Thickness[.01],Red,Line[{{a-δ,0},{a+δ,0}}]}],
Graphics[{Gray,Dashed,Line[{{a,-1.5},{a,2}}]}],
Graphics[Text[Style["a",Italic,14],{a+.1,-.1}]]
],
{{ϵ,.5,Style["ϵ",Italic]},.05,.5,.01,Appearance->"Labeled"},
{{δ,1,Style["δ",Italic]},.05,1,.01,Appearance->"Labeled"}
]

Tuto limitu si můžeme nechat ověřit Mathematicou:

{{Limit[Sin[x],x->1]},{N[Sin[1]]}}//Grid

a∈ℝ, c=+∞

(1/(|x|))->+∞ když x->0.

Manipulate[
a=0;
Show[
Plot[(1/(Abs[x])),{x,-1,1},
Exclusions->{0},
PlotStyle->{Blue,Thick},
AxesLabel->{Style["x",Italic,14],Style["1/|x|",Italic,14]},
PlotRange->{0,20},
ImageSize->400,
TicksStyle->14
],
Graphics[{Opacity[.2],Green,Rectangle[{-1,α},{1,20}]}],
Graphics[{Green,Thickness[.01],Line[{{0,α},{0,20}}]}],
Plot[(1/(Abs[x])),{x,a-δ,a+δ},Exclusions->{0},PlotStyle->{Red,Thick},PlotRange->{0,20}],
Graphics[{Opacity[.2],Lighter[Red],Rectangle[{a-δ,0},{a+δ,20}]}],
Graphics[{Thickness[.01],Red,Line[{{a-δ,0},{a+δ,0}}]}]
],
{{δ,.8,Style["δ",Italic]},.05,.8,.01,Appearance->"Labeled"},
{{α,5,Style["α",Italic]},5,19,.01,Appearance->"Labeled"}
]

Ověření:

Limit[(1/(Abs[x])),x->0]

Upozorňujeme, že Mathematica počítá v komplexním oboru, takže z pohledu reálné analýzy vrací nesprávně tuto limitu:

Limit[(1/x),x->0]

Toto je pravda pokud se na funkci 1/x díváme jakožto na funkci ℂ->ℂ. V komplexní rovině je totiž okolí bodu nula dáno jako disk se středem v nule a poloměrem ϵ

(Subscript[H, 0])(ϵ)={z∈ℂ:|z|<ϵ}

a okolí bodu ∞ (v ℂ nerozlišujeme +∞ a –∞, máme pouze jedno) je doplněk disku o daném poloměru c>0,

(Subscript[H, ∞])(c)={z∈ℂ: |z|>c}.

a=+∞, c∈ℝ

1+(Subscript[J, 0])(x)->1, když x->+∞

Manipulate[
c=1;
Show[
Plot[BesselJ[0,x]+1,{x,0,50},
PlotStyle->{Blue,Thick},
AxesLabel->{Style["x",Italic,14],Style["1+(Subscript[J, 0])(x)",Italic,14]},
PlotRange->{-0.5,2.5},
ImageSize->400,
TicksStyle->14
],
Graphics[{Gray,Dashed,Line[{{0,1},{50,1}}]}],
Graphics[{Opacity[.2],Green,Rectangle[{0,c-ϵ},{50,c+ϵ}]}],
Graphics[{Green,Thickness[.01],Line[{{0,c-ϵ},{0,c+ϵ}}]}],
Plot[BesselJ[0,x]+1,{x,α,50},
PlotStyle->{Red,Thick},
PlotRange->{-0.5,2.5}],
Graphics[{Opacity[.2],Lighter[Red],Rectangle[{α,-0.5},{50,2.5}]}],
Graphics[{Thick,Red,Line[{{α,0},{50,0}}]}]
],
{{α,.1,Style["α",Italic]},.1,40,.01,Appearance->"Labeled"},
{{ϵ,.5,Style["ϵ",Italic]},.05,.9,.01,Appearance->"Labeled"}
]

Ověření:

Limit[1+BesselJ[0,x],x->∞]